Mercurial > core / emacs/lib/graph.el

 ;;; graph.el --- Graph-oriented Extensions -*- lexical-binding: t; -*-
 
 ;; Copyright (C) 2024  The Compiler Company
 ;; Version: "0.2.0"
 ;; Author: Richard Westhaver <richard.westhaver@gmail.com>
 ;; Keywords: docs, maint, outlines, extensions
 
 ;; This program is free software; you can redistribute it and/or modify
 ;; it under the terms of the GNU General Public License as published by
 ;; the Free Software Foundation, either version 3 of the License, or
 ;; (at your option) any later version.
 
 ;; This program is distributed in the hope that it will be useful,
 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 ;; GNU General Public License for more details.
 
 ;; You should have received a copy of the GNU General Public License
 ;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
 
 ;;; Commentary:
 
 ;;
 
 ;;; Code:
 (require 'org)
 (require 'org-agenda)
 (require 'default)
 (require 'ulang)
 
 (defgroup graph nil
   "CC Graph")
 
 (defcustom org-graph-db-directory (join-paths user-org-stash-directory "graph")
   "graph database storage directory."
   :type 'directory
   :group 'graph)
 
 (defcustom org-graph-locations (list (join-paths company-org-directory "notes"))
   "List of directories to check for nodes."
   :type '(list directory)
   :group 'graph)
 
 (defcustom org-graph-include-agenda-files nil
   "When non-nil, include `org-agenda-files' in the graph."
   :type 'boolean
   :group 'graph)
 
 (defcustom org-graph-include-archive nil
   "When non-nil, include `org-arhive-location' in the graph."
   :type 'boolean
   :group 'graph)
 
 (defcustom org-graph-include-org-directory nil
   "When non-nil, include `org-directory' files in the graph."
   :type 'boolean
   :group 'graph)
 
 (defcustom org-graph-compaction-hook nil
   "Hook run when a graph is compacted to `org-graph-db'."
   :type 'hook
   :group 'graph)
 
 (defcustom org-graph-capture-hook nil
   "Hook run when a node is added to the graph."
   :type 'hook
   :group 'graph)
 
 (defvar-local org-graph nil
   "The currently active graph of org nodes.")
 
 (defcustom org-graph-db-init-script (join-paths company-source-directory "infra/scripts/org-db-init.lisp")
   "Path to a lisp script responsible for initializing the `org-graph-db-directory'.")
 
 (cl-defstruct org-graph-db-handle
   (type :rocksdb)
   (name "org-graph-db")
   get
   put
   delete
   merge
   compact
   shutdown)
 
 (defcustom org-graph-db (make-org-graph-db-handle)
   "A handle to the database backend which stores nodes and edges."
   :type 'org-graph-db-handle
   :group 'graph)
 
 (defun org-graph-from-id-locations ()
   "Populate the `org-graph' from `org-id-locations', filtering out any
 entries not under a member of `org-graph-locations'."
   (interactive)
   (setq-local org-graph (copy-hash-table (org-id-locations-load)))
   (maphash
    (lambda (k v)
      (mapc
       (lambda (x)
         (unless (string-prefix-p x (file-truename v))
           (remhash k org-graph)))
       org-graph-locations))
    org-graph))
 
 (defun org-dblock-write:links ()
   "Generate a 'links' block for the designated node.")
 
 (defun org-dblock-write:graph ()
   "Generate a 'graph' block for the designated set of nodes.")
 
 ;;; Links
 ;; See https://github.com/toshism/org-super-links/blob/develop/org-super-links.el
 (declare-function org-make-link-description-function "ext:org-mode")
 
 (defvar org-graph-edge-backlink-into-drawer "LINKS"
   "Controls how/where to insert the backlinks.
 If non-nil a drawer will be created and backlinks inserted there.  The
 default is BACKLINKS.  If this is set to a string a drawer will be
 created using that string.  For example LINKS.  If nil backlinks will
 just be inserted under the heading.")
 
 (defvar org-graph-edge-backlink-prefix 'org-graph-edge-backlink-prefix-timestamp
   "Prefix to insert before the backlink.
 This can be a string, nil, or a function that takes no arguments and
 returns a string.
 
 Default is the function `org-graph-edge-backlink-prefix-timestamp'
 which returns an inactive timestamp formatted according to the variable
 `org-time-stamp-formats' and a separator ' <- '.")
 
 (defvar org-graph-edge-backlink-postfix nil
   "Postfix to insert after the backlink.
 This can be a string, nil, or a function that takes no arguments and
 returns a string")
 
 (defvar org-graph-edge-related-into-drawer nil
     "Controls how/where to insert links.
 If non-nil a drawer will be created and links inserted there.  The
 default is `org-graph-edge-related-drawer-default-name'.  If this is set to a
 string a drawer will be created using that string.  For example LINKS.
 If nil links will just be inserted at point.")
 
 (defvar org-graph-edge-related-drawer-default-name "RELATED"
   "Default name to use for link drawer.
 If variable `org-graph-edge-related-into-drawer' is 't' use this
 name for the drawer.  See variable `org-graph-edge-related-into-drawer' for more info.")
 
 (defvar org-graph-edge-link-prefix nil
   "Prefix to insert before the link.
 This can be a string, nil, or a function that takes no arguments and
 returns a string")
 
 (defvar org-graph-edge-link-postfix nil
   "Postfix to insert after the link.
 This can be a string, nil, or a function that takes no arguments and
 returns a string")
 
 (defvar org-graph-edge-default-description-formatter org-make-link-description-function
   "What to use if no description is provided.
 This can be a string, nil or a function that accepts two arguments
 LINK and DESC and returns a string.
 
 nil will return the default desciption or the link.
 string will be used only as a default fall back if set.
 function will be called for every link.
 
 Default is the variable `org-make-link-desciption-function'.")
 
 (defvar org-graph-edge-search-function
   (cond ((require 'helm-org-ql nil 'no-error) "helm-org-ql")
         ((require 'helm-org-rifle nil 'no-error) "helm-org-rifle")
         (t 'org-graph-edge-get-location))
   "The interface to use for finding target links.
 This can be a string with one of the values 'helm-org-ql',
 'helm-org-rifle', or a function.  If you provide a custom
 function it will be called with the `point` at the location the link
 should be inserted.  The only other requirement is that it should call
 the function `org-graph-edge--insert-link' with a marker to the target link.
 AKA the place you want the backlink.
 
 Using 'helm-org-ql' or 'helm-org-rifle' will also add a new
 action to the respective action menu.
 
 See the function `org-graph-edge-link-search-interface-ql' or for an example.
 
 Default is set based on currently installed packages.  In order of priority:
 - 'helm-org-ql'
 - 'helm-org-rifle'
 - `org-graph-edge-get-location'
 
 `org-graph-edge-get-location' internally uses `org-refile-get-location'.")
 
 (defvar org-graph-edge-pre-link-hook nil
   "Hook called before storing the link on the link side.
 This is called with point at the location where it was called.")
 
 (defvar org-graph-edge-pre-backlink-hook nil
   "Hook called before storing the link on the backlink side.
 This is called with point in the heading of the backlink.")
 
 (declare-function org-graph-edge-org-ql-link-search-interface "ext:org-graph-edge-org-ql")
 (declare-function org-graph-edge-org-rifle-link-search-interface "ext:org-graph-edge-org-rifle")
 
 (defun org-graph-edge-get-location ()
   "Default for function `org-graph-edge-search-function' that reuses the `org-refile' machinery."
   (let ((target (org-refile-get-location "Super Link")))
     (org-graph-edge--insert-link (set-marker (make-marker) (car (cdddr target))
                                  (get-file-buffer (car (cdr target)))))))
 
 (defun org-graph-edge-search-function ()
   "Call the search interface specified in variable `org-graph-edge-search-function'."
   (cond ((string= org-graph-edge-search-function "helm-org-ql")
          (require 'org-graph-edge-org-ql)
          (org-graph-edge-org-ql-link-search-interface))
         ((string= org-graph-edge-search-function "helm-org-rifle")
          (require 'org-graph-edge-org-rifle)
          (org-graph-edge-org-rifle-link-search-interface))
         (t (funcall org-graph-edge-search-function))))
 
 (defun org-graph-edge-backlink-prefix ()
   "Return an appropriate string based on variable `org-graph-edge-backlink-prefix'."
   (cond ((equal org-graph-edge-backlink-prefix nil) "")
         ((stringp org-graph-edge-backlink-prefix) org-graph-edge-backlink-prefix)
         (t (funcall org-graph-edge-backlink-prefix))))
 
 (defun org-graph-edge-backlink-postfix ()
   "Return an appropriate string based on variable `org-graph-edge-backlink-postfix'."
   (cond ((equal org-graph-edge-backlink-postfix nil) "\n")
         ((stringp org-graph-edge-backlink-postfix) org-graph-edge-backlink-postfix)
         (t (funcall org-graph-edge-backlink-postfix))))
 
 (defun org-graph-edge-link-prefix ()
   "Return an appropriate string based on variable `org-graph-edge-link-prefix'."
   (cond ((equal org-graph-edge-link-prefix nil) "")
         ((stringp org-graph-edge-link-prefix) org-graph-edge-link-prefix)
         (t (funcall org-graph-edge-link-prefix))))
 
 (defun org-graph-edge-link-postfix ()
   "Return an appropriate string based on variable `org-graph-edge-link-postfix'."
   (cond ((equal org-graph-edge-link-postfix nil) "")
         ((stringp org-graph-edge-link-postfix) org-graph-edge-link-postfix)
         (t (funcall org-graph-edge-link-postfix))))
 
 (defun org-graph-edge-backlink-prefix-timestamp ()
   "Return the default prefix string for a backlink.
 Inactive timestamp formatted according to `org-time-stamp-formats' and
 a separator ' <- '."
   (concat (format-time-string (org-time-stamp-format t t) (current-time))
         " <- "))
 
 (defun org-graph-edge-default-description-formatter (link desc)
   "Return a string to use as the link desciption.
 LINK is the link target.  DESC is the provided desc."
   (let ((p org-graph-edge-default-description-formatter))
     (cond ((equal p nil) (or desc link))
           ((stringp p) (or desc p))
           ((fboundp p) (funcall p link desc))
           (t desc))))
 
 (defun org-graph-edge-backlink-into-drawer ()
   "Name of the backlink drawer, as a string, or nil.
 This is the value of variable
 `org-graph-edge-backlink-into-drawer'.  However, if the current
 entry has or inherits a BACKLINK_INTO_DRAWER property, it will be
 used instead of the default value."
   (let ((p (org-entry-get nil "BACKLINK_INTO_DRAWER" 'inherit t)))
     (cond ((equal p "nil") nil)
           ((equal p "t") "BACKLINKS")
           ((stringp p) p)
           (p "BACKLINKS")
           ((stringp org-graph-edge-backlink-into-drawer) org-graph-edge-backlink-into-drawer)
           (org-graph-edge-backlink-into-drawer "BACKLINKS"))))
 
 ;; delete related functions
 (defun org-graph-edge--find-link (id)
   "Return link element for ID."
   (save-restriction
     (org-graph-edge--org-narrow-to-here)
     (let ((link
            (org-element-map (org-element-parse-buffer) 'link
              (lambda (link)
                (when (string= (org-element-property :path link) id)
                  link)))))
       (widen)
       (if (> (length link) 1)
           (error "Multiple links found.  Canceling delete")
         (car link)))))
 
 (defun org-graph-edge--org-narrow-to-here ()
   "Narrow to current heading, excluding subheadings."
   (org-narrow-to-subtree)
   (save-excursion
     (org-next-visible-heading 1)
     (narrow-to-region (point-min) (point))))
 
 
 (defun org-graph-edge--in-drawer ()
   "Return nil if point is not in a drawer.
 Return element at point is in a drawer."
   (let ((element (org-element-at-point)))
     (while (and element
                 (not (memq (org-element-type element) '(drawer property-drawer))))
       (setq element (org-element-property :parent element)))
     element))
 
 
 (defun org-graph-edge--delete-link (link)
   "Delete the LINK.
 If point is in drawer, delete the entire line."
   (save-excursion
     (goto-char (org-element-property :begin link))
     (if (org-graph-edge--in-drawer)
         (progn
           (kill-whole-line 1)
           (org-remove-empty-drawer-at (point)))
       (delete-region (org-element-property :begin link) (org-element-property :end link)))))
 
 
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 ;; EXPERIMENTAL related into drawer
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
 (defun org-graph-edge-related-into-drawer ()
   "Name of the related drawer, as a string, or nil.
 This is the value of variable
 `org-graph-edge-related-into-drawer'.  However, if the current
 entry has or inherits a RELATED_INTO_DRAWER property, it will be
 used instead of the default value."
   (let ((p (org-entry-get nil "RELATED_INTO_DRAWER" 'inherit t)))
     (cond ((equal p "nil") nil)
           ((equal p "t") org-graph-edge-related-drawer-default-name)
           ((stringp p) p)
           (p org-graph-edge-related-drawer-default-name)
           ((stringp org-graph-edge-related-into-drawer) org-graph-edge-related-into-drawer)
           (org-graph-edge-related-into-drawer org-graph-edge-related-drawer-default-name))))
 
 (defun org-graph-edge-insert-relatedlink (link desc)
   "LINK DESC related experiment."
   (if (org-graph-edge-related-into-drawer)
       (let* ((org-log-into-drawer (org-graph-edge-related-into-drawer))
              (beg (org-log-beginning t)))
         (goto-char beg)
         (insert (org-graph-edge-link-prefix))
         (org-insert-link nil link desc)
         (insert (org-graph-edge-link-postfix) "\n")
         (org-indent-region beg (point)))
     (insert (org-graph-edge-link-prefix))
     (org-insert-link nil link desc)
     (insert (org-graph-edge-link-postfix))))
 
 (defun org-graph-edge-link-prefix-timestamp ()
   "Return the default prefix string for a backlink.
 Inactive timestamp formatted according to `org-time-stamp-formats' and
 a separator ' -> '."
   (concat (format-time-string (org-time-stamp-format t t) (current-time))
         " -> "))
 
 (defun org-graph-edge-quick-insert-drawer-link ()
   "Insert link into drawer regardless of variable `org-graph-edge-related-into-drawer' value."
   (interactive)
   ;; how to handle prefix here?
   (let ((org-graph-edge-related-into-drawer (or org-graph-edge-related-into-drawer t))
         (org-graph-edge-link-prefix 'org-graph-edge-link-prefix-timestamp))
     (org-graph-edge-link)))
 
 (defun org-graph-edge-quick-insert-inline-link ()
   "Insert inline link regardless of variable `org-graph-edge-related-into-drawer' value."
   (interactive)
   ;; how to handle prefix here?
   (let ((org-graph-edge-related-into-drawer nil)
         (org-graph-edge-link-prefix nil))
     (org-graph-edge-link)))
 
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 ;; /EXPERIMENTAL related into drawer
 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
 (defun org-graph-edge-insert-backlink (link desc)
   "Insert backlink to LINK with DESC.
 Where the backlink is placed is determined by the variable `org-graph-edge-backlink-into-drawer'."
   (let* ((org-log-into-drawer (org-graph-edge-backlink-into-drawer))
          (description (org-graph-edge-default-description-formatter link desc))
          (beg (org-log-beginning t)))
     (goto-char beg)
     (insert (org-graph-edge-backlink-prefix))
     (insert (org-link-make-string link description))
     (insert (org-graph-edge-backlink-postfix))
     (org-indent-region beg (point))))
 
 (defun org-graph-edge-links-action (marker hooks)
   "Go to MARKER, run HOOKS and store a link."
   (with-current-buffer (marker-buffer marker)
     (save-excursion
       (save-restriction
         (widen) ;; buffer could be narrowed
         (goto-char (marker-position marker))
         (run-hooks hooks)
         (call-interactively #'org-store-link)
         (pop org-stored-links)))))
 
 (defun org-graph-edge-link-builder (link)
   "Format link description for LINK."
   (let* ((link-ref (car link))
          (pre-desc (cadr link))
          (description (org-graph-edge-default-description-formatter link-ref pre-desc)))
     (cons link-ref description)))
 
 (defun org-graph-edge--insert-link (target &optional no-forward)
   "Insert link to marker TARGET at current `point`, and create backlink to here.
 Only create backlinks in files in `org-mode' or a derived mode, otherwise just
 act like a normal link.
 
 If NO-FORWARD is non-nil skip creating the forward link.  Currently
 only used when converting a link."
   (let* ((source (point-marker))
          (source-link (org-graph-edge-links-action source 'org-graph-edge-pre-link-hook))
          (target-link (org-graph-edge-links-action target 'org-graph-edge-pre-backlink-hook))
          (source-formatted-link (org-graph-edge-link-builder source-link))
          (target-formatted-link (org-graph-edge-link-builder target-link)))
     (with-current-buffer (marker-buffer target)
       (save-excursion
         (save-restriction
           (widen) ;; buffer could be narrowed
           (goto-char (marker-position target))
           (when (derived-mode-p 'org-mode)
             (org-graph-edge-insert-backlink (car source-formatted-link) (cdr source-formatted-link))))))
     (unless no-forward
       (with-current-buffer (marker-buffer source)
         (save-excursion
           (goto-char (marker-position source))
           (org-graph-edge-insert-relatedlink (car target-formatted-link) (cdr target-formatted-link)))))))
 
 
 ;;;###autoload
 (defun org-graph-edge-convert-link-to-edge (arg)
   "Convert a normal `org-mode' link at `point' to a graph link, ARG prefix.
 If variable `org-graph-edge-related-into-drawer' is non-nil move
 the link into drawer.
 
 When called interactively with a `C-u' prefix argument ignore
 variable `org-graph-edge-related-into-drawer' configuration and
 do not modify existing link."
   (interactive "P")
   (let ((from-m (point-marker))
         (target (save-window-excursion
                   (with-current-buffer (current-buffer)
                     (save-excursion
                       (org-open-at-point)
                       (point-marker))))))
     (org-graph-edge--insert-link target (or arg (not org-graph-edge-related-into-drawer)))
     (goto-char (marker-position from-m)))
 
   (when (and (not arg) (org-graph-edge-related-into-drawer))
     (let ((begin (org-element-property :begin (org-element-context)))
           (end (org-element-property :end (org-element-context))))
       (delete-region begin end))))
 
 ;;;###autoload
 (defun org-graph-edge-delete-link ()
   "Delete the link at point, and the corresponding reverse link.
 If no reverse link exists, just delete link at point.
 This works from either side, and deletes both sides of a link."
   (interactive)
   (save-window-excursion
     (with-current-buffer (current-buffer)
       (save-excursion
         (let ((id (org-id-get (point))))
           (org-open-at-point)
           (let ((link-element (org-graph-edge--find-link id)))
             (if link-element
                 (org-graph-edge--delete-link link-element)
               (message "No backlink found. Deleting active only.")))))))
   (org-graph-edge--delete-link (org-element-context)))
 
 ;;;###autoload
 (defun org-graph-edge-store-link (&optional GOTO KEYS)
   "Store a point to register for use in function `org-graph-edge-insert-link'.
 This is primarily intended to be called before `org-capture', but
 could possibly even be used to replace `org-store-link' IF
 function `org-graph-edge-insert-link' is used to replace
 `org-insert-link'.  This has not been thoroughly tested outside
 of links to/form org files.  GOTO and KEYS are unused."
   (interactive "P")
   (ignore GOTO)
   (ignore KEYS)
   (save-excursion
     ;; this is a hack. if the point is at the first char of a heading
     ;; the marker is not updated as expected when text is inserted
     ;; above the heading. for example a capture template inserted
     ;; above. that results in the link being to the heading above the
     ;; expected heading.
     (goto-char (line-end-position))
     (let ((c1 (make-marker)))
       (set-marker c1 (point) (current-buffer))
       (set-register ?^ c1)
       (message "Link copied"))))
 
 ;; not sure if this should be autoloaded or left to config?
 ;;;###autoload
 (advice-add 'org-capture :before #'org-graph-edge-store-link)
 
 ;;;###autoload
 (defun org-graph-edge-insert-link ()
   "Insert a super link from the register."
   (interactive)
   (let* ((target (get-register ?^)))
     (if target
         (progn
           (org-graph-edge--insert-link target)
           (set-register ?^ nil))
       (message "No link to insert!"))))
 
 ;;;###autoload
 (defun org-graph-edge-link ()
   "Insert a link and add a backlink to the target heading."
   (interactive)
   (org-graph-edge-search-function))
 
 (provide 'graph)
 ;; graph.el ends here