1 files changed, 31 insertions, 0 deletions
diff --git a/subprojects/gst-plugins-bad/sys/opensles/meson.build b/subprojects/gst-plugins-bad/sys/opensles/meson.build
new file mode 100644
index 0000000000..a7f1a4d48d
--- /dev/null
+++ b/subprojects/gst-plugins-bad/sys/opensles/meson.build
@@ -0,0 +1,31 @@
+opensles_sources = [
+  'openslescommon.c',
+  'openslesringbuffer.c',
+  'openslessink.c',
+  'openslessrc.c',
+  'opensles.c',
+  'openslesplugin.c',
+]
+
+opensles_option = get_option('opensles')
+if opensles_option.disabled()
+  subdir_done()
+endif
+
+have_opensles_h = cc.has_header('SLES/OpenSLES.h')
+if not have_opensles_h and opensles_option.enabled()
+  error('opensles plugin enabled but SLES/OpenSLES.h not found')
+endif
+opensles_dep = cc.find_library('OpenSLES', required : opensles_option)
+
+if have_opensles_h and opensles_dep.found()
+  gstopensles = library('gstopensles',
+    opensles_sources,
+    c_args : gst_plugins_bad_args,
+    include_directories : [configinc],
+    dependencies : [gstaudio_dep, opensles_dep],
+    install : true,
+    install_dir : plugins_install_dir)
+  pkgconfig.generate(gstopensles, install_dir : plugins_pkgconfig_install_dir)
+  plugins += [gstopensles]
+endif